// "Information wants to be one"
// 1998 Anders Sandberg, asa@nada.kth.se

#include "colors.inc"
#include "textures.inc"
#include "stones.inc"

#declare Numbers=1
#declare DNA=1
#declare Fuss=1
#declare Fog=1

camera {
   location <0, 0,  -10>
   look_at <0, 0, 0>
}

#declare Lig=<0.1,0.1,0.1>
//#declare Lig=<0.5,0.5,0.5>

object {
   light_source {
      <0, 0, 0>
     color rgb Lig
   }
}
object {
   light_source {
      <0, -3, 0>
     color rgb Lig
   }
}
object {
   light_source {
      <0, 3, 0>
     color rgb Lig
   }
}
object {
   light_source {
      <0, -6, 0>
     color rgb Lig
   }
}
object {
   light_source {
      <0, 6, 0>
     color rgb Lig
   }
}


#declare A=seed(1234)

#declare h = 0.02
#declare k = 0.6

#declare Ri=0.3
#declare Ro=2.0

#declare DR=180/3.1415
#declare IT=7


#declare S=-12
#while (S<12)

#declare TEX="0"
#if (rand(A)<0.5)
#declare TEX="1"
#end

#if (Numbers=1)
object{
  text { ttf "timrom.ttf" TEX 0.2, 0}
//box {<0,0,0>,<0.5,1,0.1>}
  scale 0.4

  rotate <0,90,0>
//  sphere{<0,0,0>,0.1} 
  translate <Ro,S*k,0>
  rotate <0,S*DR+180,0>

  texture{Silver3 pigment{Red}}
}
#end

#if (DNA=1)
#declare SS=S
#while (SS<S+h*5)

object{
  sphere{<Ri,0,0>,0.05} 
  rotate <0,0,IT*SS*DR>
  translate <Ro,SS*k,0>
  rotate <0,SS*DR,0>

  texture{Silver3 pigment{Green}}
}

object{
  sphere{<Ri,0,0>,0.05} 
  rotate <0,0,IT*SS*DR+120>
  translate <Ro,SS*k,0>
  rotate <0,SS*DR,0>

  texture{Silver3 pigment{Green}}
}
#declare SS=SS+h
#end

object {
  cylinder {<Ri,0,0>,<-Ri/2,Ri*sqrt(3)/2,0>,0.02}

  rotate <0,0,IT*S*DR>
  translate <Ro,S*k,0>
  rotate <0,S*DR,0>
  
  texture{Silver3 pigment{Green}}
}
#end

#declare S=S+h*5
#end

#if (Fuss=1)
#declare Fussball =
object {
  sphere {<0,0,0>,1}
  
  texture {
    pigment { color rgbt <1, 1, 1, 1> }    
    halo {
      emitting
      spherical_mapping
      linear
      color_map {
	[ 0 color rgbt <1, 0.5, 0, 1> ]
	[ 1 color rgbt <1, 1, 0, 0> ]
      }
      samples 10
    }
  }
  hollow
  no_shadow
}

object {Fussball scale .8 translate <0,-6,0>}
object {Fussball scale .9 translate <0,-3,0>}
object {Fussball}
object {Fussball scale 1.1 translate <0,3,0>}
object {Fussball scale 1.2 translate <0,6,0>}
#end


#declare DI=10
#declare AN=20

#declare SUR=texture{
  pigment {
    bozo
    turbulence 2.0
    
    color_map {
      [0.0 color Gray]
      [0.2 color Gray]
      [0.25 color rgb <1,0.8,0.8>]
      [0.3 color Gray]
      [0.45 color Gray]
      [0.5 color rgb <0.8,1,0.8>]
      [0.55 color Gray]
      [0.7 color Gray]
      [0.75 color rgb <0.8,0.8,1>]
      [0.8 color Gray]
      [1.0 color Gray]
    }
  } 
  finish{Dull}
}
#declare SUR2=texture{
  pigment {
    bozo
    turbulence 2.0
    
    color_map {
      [0.0 color Clear]
      [0.2 color Clear]
      [0.25 color rgb <1,0.8,0.8>]
      [0.3 color Clear]
      [0.45 color Clear]
      [0.5 color rgb <0.8,1,0.8>]
      [0.55 color Clear]
      [0.7 color Clear]
      [0.75 color rgb <0.8,0.8,1>]
      [0.8 color Clear]
      [1.0 color Clear]
    }
  } 
  finish{Dull}
}

object {
  cylinder {<0,-100,0>,<0,100,0>,DI}

/*  union {
    plane {<0,0,-1>,DI rotate <AN,0,0>}
    plane {<0,0,-1>,DI rotate <AN,60,0>}    
    plane {<0,0,-1>,DI rotate <AN,-60,0>}
    plane {<0,0,-1>,DI rotate <AN,120,0>}    
    plane {<0,0,-1>,DI rotate <AN,-120,0>}
    plane {<0,0,-1>,DI rotate <AN,0,0>}
  }*/
  hollow
  texture {SUR}
  texture {SUR2}
}

#if (Fog=1)
atmosphere {
  type 1
  samples 10
  distance 40
  scattering 0.05
  aa_level 4
  aa_threshold 0.1
  jitter 0.2

}
#end