// "Gray Goo"
// 1998 Anders Sandberg


#include "colors.inc"
#include "textures.inc"

camera {
   location <-2, 5,  -10>
   look_at <0, 2, 0>
}

object {
   light_source {
      <-500, 500, -500>
      color White
   }
}

#declare R2=seed(11)
#declare Goo =texture{Silver1}


#declare X=-10
#while (X<14)
#declare Y=1
#while (Y<3)
#declare Z=-10
#while (Z<14)

#declare D=4/(1+.3*(X*X+Z*Z))+4/(1+.3*((X-10)*(X-10)+(Z-10)*(Z-10)))
#declare D2=5/(1+.2*(X*X+Z*Z))

//sphere {<0,0,0>,1
julia_fractal {
  <rand(R2)*2-1,rand(R2)*2-1,rand(R2)*2-1,rand(R2)*2-1>
  quaternion
  sqr
  max_iteration 8
  precision 15
  texture {Goo}
  rotate <0,rand(R2)*360,rand(R2)*360>
  translate <X,Y+D,Z>
}


julia_fractal {
  <rand(R2)*2-1,rand(R2)*2-1,rand(R2)*2-1,rand(R2)*2-1>
  quaternion
  sqr
  max_iteration 8
  precision 15
  texture {Goo}
  rotate <0,rand(R2)*360,rand(R2)*360>
  translate <X,Y+D2,Z>
  rotate <0,50,0>
  translate <-10,-2,30>
}


// sphere{<X,Y,Z>,0.2 texture {Silver3}}

#declare Z=Z+1
#end
#declare Y=Y+1
#end
#declare X=X+1
#end


plane {
  <0,1,0>,0
  
  texture{Goo normal{bumps 1.0 scale .05}}
}


fog {
  distance 150
  colour rgb<0.3, 0.3, 0.4>
  fog_type 2
  fog_offset 25
  fog_alt 3
  turbulence 0.5
  turb_depth 0.5
}