// "Kindergarten"
// 1998 Anders Sandberg

#include "colors.inc"
#include "textures.inc"
#include "stones.inc"

#declare Moon=1
#declare Ground=1
#declare Hill=1
#declare Mono=1
#declare Fog=1

camera {
   location <0, 0,  -17>
   look_at <0, 0, 0> 
}

object {
   light_source {
      <0, 50000, -10000>
      color White
   }
}

#if (Moon=1)
object {
  sphere {<0,0,1000>,100}
  rotate <-20,0,0>
  texture {  
    pigment {
      granite 
      turbulence 0.7
      color_map {
	[0.0 color rgb <1,1,1>]
	[0.3 color rgb <0.6,0.6,0.6>]
	[0.4 color rgb <0.35,0.35,0.35>]
	[1.0 color rgb <0.3,0.3,0.3>]
      }
      scale 10
    }
      
    finish {diffuse 1.0  ambient 0}
    normal {granite 0.5}
    scale 10
  }
  
}
#end

#if (Ground=1)

/*
  
  texture {
    pigment {
      color <.85,.5,.15>
    }
    finish {
      ambient.25
      diffuse.6
      crand.5
    }
    normal {
      crackle 0.35
      turbulence.25
      frequency 5
    }
  }
*/

object {
  plane {<0,1,0>,-3}
  
  texture {
    pigment {
      bozo
      turbulence 0.3
      color_map{
	[0.0     color <.85,.5,.15>]
	[0.4     color <.80,.45,.10>]
	[0.7     color <.85,.5,.15>*0.7]
	[1.0     color <.85,.5,.15>*0.6]
      }
      scale <7,5,5>
      rotate <0,30,0>
    }

    finish {
      ambient.25
      diffuse.6
      //crand.5
    }

    normal {
      average 
      normal_map {
	[ 0.5      crackle 1.0
	  turbulence 0.3
	  slope_map {
	    [0 <0,0>]
	    [0.05 <0.1 2>]
	    [0.05 <0.1 0>]
	    [1   <0.1 0>]
	  }
	]
	[0.5 granite 0.5]
      }
    }
  }
}
#if (Hill=1)
object {
  height_field {
    tga "/tmp/hill2.tga"
  }
  translate <-.5,0,-.5>
  rotate <0,45,0>
  scale <300,60,400>
  translate <100,-12,300>

  texture {
    pigment {
      gradient y 
      turbulence 0.5
      color_map {
	[0.0 color <.85,.5,.15>]
	[0.5 color <.55,.4,.15>]
	[1.0 color <.65,.5,.15>]
      }
      scale 10
    }
    finish {
      ambient.25
      diffuse.6
    }
  }
}
#end
#end

#if (Mono=1)
      
#declare Monolith =
object {
  box {<-2,0,0>,<2,9,1>}
  
  texture {
    pigment {Black}
//    pigment {White}
    finish {Shiny reflection 0.3}
  }
}

object {
  Monolith
  rotate <0,30,0>
  translate <0,-3,7>
}

object {
  Monolith
  rotate <0,50,0>
  scale 0.2
  translate <-6,-3,2>
}

object {
  Monolith
  rotate <0,60,0>
  scale 0.2
  translate <-5,-3,4>
}


object {
  Monolith
  rotate <0,50,0>
  scale 0.2
  translate <-3.5,-3,2.5>
}

object {
  Monolith
  translate <3,0,-2>
  rotate <0,21,0>
  scale 0.2
  translate <-2.75,-3,1.6>
}

object {
  Monolith
  rotate <0,18,0>
  scale 0.2
  translate <-1.25,-3,1.4>
}

object {
  Monolith
  rotate <-90,185,0>

  scale 0.2
  translate <-0.3,-3,0.5>
}


#end

#if (Fog=1)

fog {
  distance 150
  colour rgb<0.3, 0.5, 0.2>
  fog_type 2
  fog_offset 25
  fog_alt 3
  turbulence 0.1
  turb_depth 0.2
}

fog {
  distance 150
//  colour rgb<0.5, 0.1, 0.1>
  colour rgb<0.5, 0.3, 0.3>
  fog_type 2
  fog_offset 15
  fog_alt 4
  turbulence 0.2
  turb_depth 0.2
}

fog {
  distance 150
  colour rgb<0.1, 0.1, 0.6>
  fog_type 2
  fog_offset 10
  fog_alt 2
}
#end


/*

  quartic {
    < 0,   0,   0,   0,   0,   0,   0,   0,   1,
      0,   0,   0,   0,   0,   0,   0,   0,   0,
      0,   0,   0,   0,   0,   0,   1,   0,   0,
      0,   0,   0,   0,   0,   0,  1, -1 >
    sturm
    hollow
    clipped_by { // bounded_by speeds up the render,
                 // see bounded_by
                 // explanation later
                 // in docs for more info.
     sphere { <0, 0, 0>, 3 }
    }
    texture {pigment{White} finish{Dull}}
    rotate <-90,0,0>

    scale <3,1,1>
    rotate <0,45,0>
  }



*/