// "Blood Music"
// 1998 Anders Sandberg

#include "colors.inc"
#include "textures.inc"
#include "stones.inc"

camera {
   location <0, 2,  -10>
   look_at <0, 0, 0>
}

object {
   light_source {
      <-500, 500, -500>
      color White
   }
}


#declare SIZ=10
#declare R=seed(123)

#declare TT=0
#while(TT<3)

blob {
  threshold 0.5
#declare X=-SIZ
#while (X<SIZ)
#declare Y=-SIZ
#while (Y<SIZ)
  sphere {<X+rand(R),0,Y+rand(R)>,1,0.5}
#declare Y=Y+1
#end
#declare X=X+1
#end

  texture {
    Silver3
    pigment {color Brown}
    
    normal {
      crackle
      scale .1
    }
  }
  translate <2*SIZ*(TT-TT*(TT-1)),0,2*SIZ*TT>
}

#declare TT=TT+1
#end


#declare Y=0
#while (Y<80)

blob {
  threshold 0.5
#declare X=-1
#while (X<20)
  sphere {<8+Y+rand(R)-rand(R),X/3,rand(R)-rand(R)>,1,0.5}
  sphere {<8+Y+rand(R)-rand(R),(X+0.5*rand(R))/3,rand(R)-rand(R)>,0.3,-0.25}
#declare X=X+1
#end
  rotate <0,-Y*5,0>
  texture {
    Silver3
    finish {reflection 0.05}
    pigment {
      leopard
      color_map {
	[0.0  color Red]
	[0.3  color Khaki]
	[0.6  color Red]
	[1.0  color Red]
      }
    }
    normal {
      leopard
      scale .1
    }
  }
  scale .5
}

#declare Y=Y+4
#end


object {
  plane {
    <0,1,0>,-.2
  }

  texture {
    pigment {
      color rgb <0.6,0.6,0.3>
    }
    finish {
      Shiny
      reflection 0.3
    }
    normal {
      ripples 0.35
      scale 2
    }
  }
}

fog {
  distance 50
  colour rgbf<1.0, 1.0, 1.0, 1.0>
  fog_type 2
  fog_offset 2
  fog_alt 3
  turbulence 0.1
  turb_depth 0.2
}

background {color rgb <0.2,0.7,0.7>}

#declare RR=3
#declare ZH=2
#declare C=3.1415/180
#declare D=60

#declare Torn =
blob {
  threshold 0.3
#declare Z=0
#while (Z<24)
#declare T=0
#while (T<360)

#declare RRR=RR/(1+Z)
cylinder {<RRR*cos(C*T),Z,RRR*sin(C*T)>,<RR*cos(C*(T+D))/(Z+1+ZH),Z+ZH,RR*sin(C*(T+D))/(Z+1+ZH)>,0.25,0.5}
cylinder {<RRR*cos(C*T),Z,RRR*sin(C*T)>,<RR*cos(C*(T-D))/(Z+1+ZH),Z+ZH,RR*sin(C*(T-D))/(Z+1+ZH)>,0.25,0.5}

#declare T=T+D
#end
#declare Z=Z+ZH
#end
 texture {Silver3}
translate <0,-1,0>
}

object {Torn}

object {Torn translate <-30,0,55>}
object {Torn translate <-16,0,50>}


/*


blob {
  threshold 0.4

  cylinder {<1,0,3>,<0,4,2>, 0.5, 0.5}
  cylinder {<-1,0,3>,<0,4,2>, 0.5, 0.5}
  cylinder {<1,0,2>,<0,4,2>, 0.5, 0.5}
  cylinder {<-1,0,2>,<0,4,2>, 0.5, 0.5}
  cylinder {<1,0,1>,<0,4,1>, 0.5, 0.5}
  cylinder {<-1,0,1>,<0,4,1>, 0.5, 0.5}
  cylinder {<1,0,0>,<0,4,0>, 0.5, 0.5}
  cylinder {<-1,0,0>,<0,4,0>, 0.5, 0.5}
  cylinder {<1,0,-1>,<0,4,0>, 0.5, 0.5}
  cylinder {<-1,0,-1>,<0,4,0>, 0.5, 0.5}
  cylinder {<0,4,2>,<0,4,0>, 0.5, 0.5}

  rotate <0,45,0>
  texture {
    Rust
    finish {Shiny}
    normal {leopard 0.1 scale <1,0.1,1>}
  }
  translate <0,-0.5,0>
}

*/